Renaming files: windows re-selects entire filename when other files resync

Yup, this is still happening. It seems to be the exact same issue as described here:

https://answers.microsoft.com/en-us/windows/forum/all/renaming-files-annoying-automatic-re-selection-of/3e451ce8-282a-4638-88ee-fd9f7cca2536

https://superuser.com/questions/237389/windows-filename-suddenly-gets-selected-again-while-renaming-it

https://onedrive.uservoice.com/forums/913522-onedrive-on-windows/suggestions/35362708-bug-explorer-reselects-entire-filename-when-edit

Basically, Windows File Explorer redraws the window every time Dropbox (or any other cloud storage service, really) syncs. If that happens while renaming a file, boom, you get this obnoxious problem. Drives me nuts. I've lost count of the number of times that I've accidentally overwritten the name of an entire file or folder and had to frantically change it back. Dropbox staff, I would be forever grateful to you if you solved this issue.

To sort of work around this problem, I've created the following AutoHotkey script which is triggered by Ctrl + R and, every time, moves the text cursor to just before the file extension:

GroupAdd, FileExplorer, ahk_class CabinetWClass ; Normal window
GroupAdd, FileExplorer, ahk_class #32770, ShellView ; Save as / open window
GroupAdd, FileExplorer, ahk_class WorkerW ; Desktop view

; FileExplorer_GetSelection() is from a third party
FileExplorer_GetSelection(){
	WinGetClass, winClass, % "ahk_id" . hWnd := WinExist("A")
	if !(winClass ~="Progman|WorkerW|(Cabinet|Explore)WClass")
		Return
	
	shellWindows := ComObjCreate("Shell.Application").Windows
	if (winClass ~= "Progman|WorkerW")
		shellFolderView := shellWindows.FindWindowSW(0, 0, SWC_DESKTOP := 8, 0, SWFO_NEEDDISPATCH := 1).Document
	else {
		for window in shellWindows
			if (hWnd = window.HWND) && (shellFolderView := window.Document)
				break
	}
	for item in shellFolderView.SelectedItems
		result .= (result = "" ? "" : "`n") . item.Path
	if !result
		result := shellFolderView.Folder.Self.Path
	Return result
}

Move_TextCursorToEndOfFileOrFolderName(Name){
	SendInput, {End}
	
	DotPosition := InStr(Name, ".", False, 0) ; 0 makes it search from the right-hand side
	
	If ((Name != "") And (DotPosition)){
		Length := StrLen(Name)
		MoveAmount := Length - DotPosition + 1 ; + 1 ensures that the text cursor is moved to the left-hand side of the file extension
		SendInput, {Left %MoveAmount%}
	}
}

#If WinActive("ahk_group FileExplorer")
	; Ctrl and R → Invoke file rename, deselect whole file name, and move text cursor to (1) the end of the name if a folder or extensionless file or (2) the end of the file name but before the file extension.
	^r::
		Path := FileExplorer_GetSelection()
		SendInput, {F2}
		SplitPath, Path, Name
		Move_TextCursorToEndOfFileOrFolderName(Name)
	Return
#If

I hope it helps others while this problem remains.